LoadVars.onLoad

Доступность

Flash Player 6.

Синтаксис

my_lv.onLoad = function(success:Boolean) {
  // ваш код
}

Параметры

success Булева величина, показывающая, успешно (true) или нет (false), прошел процесс загрузки.

Возвращает

Булева величина.

Описание

Обработчик события; вызывается, когда загрузка данных методом LoadVars.load()или LoadVars.sendAndLoad(), завершена. Если операция завершена успешно, my_lv содержит загруженные переменные, которые становятся доступны с момента трансляции оповещения о событии.

По умолчанию этот обработчик неопределен.

Обработчик схож с обработчиком XML.onLoad.

Пример

В следующем примере на Сцену необходимо добавить компонет TextInput name_ti, компонент TextArea result_ta и компонент Button submit_button. При нажатии на кнопку Login создаются два объекта LoadVars: send_lv и result_lv. Объект send_lv получает введенное имя пользователя у компонента name_ti и отправляет на обработку скрипту greeting.cfm. Результат работы скрипта загружается в объект result_lv, после чего ответ сервера отображается в компоненте TextArea (result_ta).

var submitListener:Object = new Object();
submitListener.click = function(evt:Object) {
  var result_lv:LoadVars = new LoadVars();
  result_lv.onLoad = function(success:Boolean) {
    if (success) {
      result_ta.text = result_lv.welcomeMessage;
    } else {
      result_ta.text = "Ошибка подключения к серверу.";
    }
  };
  var send_lv:LoadVars = new LoadVars();
  send_lv.name = name_ti.text;
  send_lv.sendAndLoad("http://www.flash-mx.com/mm/greeting.cfm", result_lv, "POST");
};
submit_button.addEventListener("click", submitListener);

Подробный пример находится в файле login.fla файл в папке HelpExamples. Обычно папка HelpExamples находится по следующему пути:

Windows: \Program Files\Macromedia\Flash MX 2004\Samples\HelpExamples\
Macintosh: HD/Applications/Macromedia Flash MX 2004/Samples/HelpExamples/

LoadVars.loaded, LoadVars.load(), LoadVars.sendAndLoad()

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление